这是一个很简单系统，TB系统里自带有的。我们直接先看它的买卖规则。

策略说明:

基于平移的高点和低点均线通道与K线中值突破进行判断

系统要素:

1. Range Leader是个当前K线的中点在之前K线的最高点上, 且当前K线的振幅大于之前K线的振幅的K线

2. 计算高点和低点的移动平均线

入场条件:

1、上根K线为RangeLead，并且上一根收盘价大于N周期前高点的MA，当前无多仓，则开多仓

2、上根K线为RangeLead，并且上一根收盘价小于N周期前低点的MA，当前无空仓，则开空仓

出场条件:

1. 开仓后，5个K线内用中轨止损，5个K线后用外轨止损

这简单的系统，你不能说它很好，也不能说它不好，就看你做交易的时候怎么把握了。代码解读如下：

Params

Numeric AvgLen(20); // 声明数值参数AvgLen，初值为20，即高低点均线计算周期//

Numeric AbsDisp(5); // 声明数值参数AvsDisp，初值为5，即高低点均线前移周期//

Numeric ExitBar(5); // 声明数值参数ExitBar，初值为5，即为止损周期参数，该周期以前中轨止损，以后外轨止损。//

Vars

NumericSeries UpperAvg(0); // 声明序列变量UpperAvg，初值0，即通道上轨//

NumericSeries LowerAvg(0); // 声明序列变量LowerAvg，初值0，即通道下轨//

NumericSeries ExitAvg(0); // 声明序列变量ExitAvg，初值0，即通道中轨//

BoolSeries RangeLeadB(False); // 声明序列布尔型变量RangeLeadB，初值为假//

NumericSeries MedianPrice; // 声明序列变量MedianPrice，即K线中价//

Numeric minpoint; // 声明序列变量minpoint，即最小变动价位。//

NumericSeries range; // 声明序列变量range，即为振幅。//

Begin

If(!CallAuctionFilter()) Return;// 集合竞价和小节休息过滤。//

// 指标计算。//

minpoint = Minmove*PriceScale; // 最小变动价位固定公式了。//

range = High - Low;//变量range = 高价 - 低价。//

UpperAvg = Average(High[AbsDisp], AvgLen); //把相应值返回函数Average求值了，即计算N周期前高点的均线了，N=参数AbsDisp值为5。//

LowerAvg = Average(Low[AbsDisp], AvgLen); // 把相应值返回函数Average求值了，计算N周期前低点的均线了，N=参数AbsDisp值为5.//

MedianPrice = (High + Low)*0.5; // 代入相应值，计算得变量MedianPrice值，即为计算K线中点。//

ExitAvg = Average(MedianPrice[AbsDisp], AvgLen); // 同样的，把相应值返回函数Average求值，即计算N周期前K线中点的均线了，N=参数AbsDisp值为5.//

RangeLeadB = MedianPrice > High[1] and Range > Range[1]; // 当K线中点大于前一根K线高点并且振幅 大于上一根振幅时，RangeLeadB为真。//

// 开仓买卖系统入场//

If(MarketPosition == 0)//没有持仓情况下。//

{

If(RangeLeadB[1] and Close[1] > UpperAvg[1]) // 假如上根K线RangeLeadB为真，并且上一根收盘价大于N周期前高点的均线，当前无多仓，则开多仓。//

{

Buy(0,Open);//以开盘价，开仓买入。//

}

}

// 平仓出场。//

If(MarketPosition == 1 and BarsSinceEntry > 0) // 持有多单，并且建仓位置的k线数位大于0.//

{

If(BarsSinceEntry <= ExitBar ) //开仓后N根K线内用中轨止损，N根K线后用上轨止损，N=参数ExitBar，其实就是建仓位置小于等于5.//

{

If(Low <= ExitAvg) //假如低价小于等于变量ExitAvg值，即中轨。//

{

Sell(0,Min(Open,ExitAvg));//取开盘价与中轨价的小值，平仓。//

}

}

Else If(BarsSinceEntry > ExitBar)//假如建仓位置位数大于5的。//

{

If(Low <= UpperAvg - minpoint) //假如低价小于等于上轨减去最小跳动价的。//

{

Sell(0,Min(Open,UpperAvg - minpoint));//平仓的。//

}

}

}

End

这只是做多的，开空的规则反过来就行，代码解读没有什么区别，直接附上做空代码及结果如下：

Params

Numeric AvgLen(20);

Numeric AbsDisp(5);

Numeric ExitBar(5);

Vars

NumericSeries UpperAvg(0);

NumericSeries LowerAvg(0);

NumericSeries ExitAvg(0);

BoolSeries RangeLeadS(False);

NumericSeries MedianPrice;

Numeric minpoint;

NumericSeries range;

Begin

If(!CallAuctionFilter()) Return;

minpoint = Minmove*PriceScale;

range = High - Low;

UpperAvg = Average(High[AbsDisp], AvgLen);

LowerAvg = Average(Low[AbsDisp], AvgLen);

MedianPrice = (High + Low)*0.5;

ExitAvg = Average(MedianPrice[AbsDisp], AvgLen);

RangeLeadS = MedianPrice < Low[1] and Range > Range[1];

If(MarketPosition == 0)

{

If(RangeLeadS[1] and Close[1] < LowerAvg[1])

{

Sellshort(0,Open);

}

}

If(MarketPosition == -1 and BarsSinceEntry > 0)

{

If(BarsSinceEntry <= ExitBar)

{

If(High >= ExitAvg)

{

Buytocover(0,Max(Open,ExitAvg));

}

}

Else If(BarsSinceEntry > ExitBar)

{

If(High >= LowerAvg + minpoint)

{

Buytocover(0,Max(Open,LowerAvg + minpoint));

}

}

}

End

要做成一个完整的系统其实很简单的，就是把上面来合起来就可以了，这应该不需要我再写了吧。这代码是没有画线的，要是觉得看着空空的k线图不理解，可以添加下列这么一小段画线代码，很方便看进场买卖的价位的，如下：

PlotNumeric("lineu",UpperAvg);

PlotNumeric("lineM",ExitAvg);

PlotNumeric("lingd",LowerAvg);

画出来跟布林带有点像，但又不一样的，有兴趣的自己观测看了。完整买卖系统我就不写了，但它们的结果我可以附上，如下：